home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
BBS Toolkit
/
BBS Toolkit.iso
/
windows
/
wwax10.zip
/
WINGWAX.WAS
< prev
next >
Wrap
Text File
|
1993-03-04
|
3KB
|
109 lines
;WingWax Script v1.0
;**********************************************************
integer status
integer cserve
string USER_ID
string PWD
string forum
string wingwax_for = "\wingwax.for"
string forum_file = $PWTASKPATH
;**********************************************************
PROC MAIN
;**********************************************************
call SET_PARAMS
call PROMPT_FOR_FORUM
call CALL_CIS
when target 0 "Connect time =" call logoff
while 1
endwhile
endproc
;**********************************************************
PROC LOGOFF
;**********************************************************
hangup
exit
endproc
;**********************************************************
PROC PROMPT_FOR_FORUM
;**********************************************************
strcat forum_file wingwax_for
dialogbox 100 50 115 165 2 "WingWax 1.0"
text 15 5 85 10 center "Forums"
flistbox 15 15 85 60 forum_file single forum sort
pushbutton 25 85 65 12 "&Dial" normal
pushbutton 25 105 65 12 "&Cancel" cancel
text 15 130 85 10 center "Silverwing Systems"
text 15 140 85 10 center "PO Box 383"
text 15 150 85 10 center "Tallahassee, FL 32302"
enddialog
status = $DIALOG
while status != 10
if status == 1
exit
endif
status = $DIALOG
endwhile
endproc
;**********************************************************
PROC CALL_CIS
;**********************************************************
transmit "ATDT"
transmit $D_NUMBER
transmit "^M^J"
waitfor "CONNECT"
alarm 1
transmit "^M"
transmit "^M"
waitfor "HOST NAME:"
transmit "CIS"
transmit "^M"
waitfor "User ID:"
transmit USER_ID
transmit "^M"
waitfor "Password:"
transmit PWD
transmit "^M"
waitfor "!"
transmit "go "
transmit forum
transmit "^M"
waitfor "Press <CR> !"
transmit "^M"
endproc
;**********************************************************
proc SET_PARAMS
;**********************************************************
set baudrate default
set connection logging on
set terminal sbpages 10
set terminal type 5
set terminal rows 29
set terminal columns 80
set autosize window
set port parity even
set port databits 7
set port stopbits 1
set protocol CISB
dialfind "Compuserve" cserve
if not found
errormsg "Can't find CompuServe entry"
exit
endif
set dialdir access cserve
fetch password PWD
fetch userid USER_ID
endproc
;**********************************************************